Dígito de Control de la entidad bancaria en Excel

El Dígito de Control de la entidad bancaria en Excel (DC) permite comprobar la validez de los números de cuenta y reducir la posibilidad de errores.

Formado por dos dígitos. El primero valida conjuntamente los códigos de entidad y de oficina; el segundo, valida el número de cuenta.

Emplearemos las siguientes funciones, anidándolas:

• Función EXTRAE. Devuelve un número específico de caracteres de una cadena de texto, empezando en la posición que especifique.
• Función RESIDUO. Devuelve el resto de la división.
• Función SUMAPRODUCTO. Devuelve la suma de los productos de los componentes de la matriz correspondiente.
• Función FILA. Devuelve el número de fila de una referencia.
• Función INDIRECTO. Devuelve una referencia indicada por un valor de texto.
• Función CONCATENAR. Une varios elementos de texto en uno solo.
• Función DERECHA. Devuelve los caracteres situados en el extremo derecho de un valor de texto.

• En la celda A2, situamos el número de la entidad (los 4 primeros dígitos) donde radica la cuenta y lo proporciona el Banco de España.
• En la celda B2, situamos el número de la oficina (los 4 dígitos siguientes) que identifica la oficina donde tenemos abierta la cuenta.
• En la celda C2, situamos el número de la cuenta (los 10 últimos dígitos) que identifica al cliente.

1. Ir a: Celda E2 / Escribir:=EXTRAE(12345678910;11 – RESIDUO(SUMAPRODUCTO (EXTRAE(A2&B2; FILA(INDIRECTO(“1:8”)); 1)*(EXTRAE(37498625; FILA(INDIRECTO(“1:8”));1)+1));11);1)Como la fórmula que muestra el primer dígito de control.
2. Ir a: Celda F2 / Escribir:=EXTRAE(12345678910;11 – RESIDUO(SUMAPRODUCTO (EXTRAE(C2; FILA(INDIRECTO(“1:10”)); 1)*(EXTRAE(0&137498625; FILA(INDIRECTO(“1:10”));1)+1));11);1)Como la fórmula que muestra el segundo dígito de control.
3. Ir a: Celda G2 / Escribir:=CONCATENAR(A2;B2;E2;F2;C2)Para obtener el número completo del Código Cuenta Cliente (CCC).

El Código de Cuenta Cliente (CCC) está siendo sustituido por el IBAN (International Bank Account Number), que es una codificación internacional que incluye el CCC, e identifican una cuenta determinada en una entidad financiera en cualquier lugar del mundo.

• Dos primeros caracteres, indican el país (ES para España).
• Los dos siguientes, indican los dígitos de control IBAN.
• El resto de números, indican el Código Cuenta Cliente (CCC).

La determinación de los dos Dígitos de Control se realiza de acuerdo a las especificaciones de la Norma bancaria 34 de la AEB (Asociación Española de Banca).

1. Ir a: Celda I2 / Escribir:=DERECHA(0&98 -RESIDUO(RESIDUO (RESIDUO(RESIDUO (EXTRAE(G2;1;8); 97)&EXTRAE(G2;9;8); 97)& EXTRAE(G2&142800;17;8); 97)& EXTRAE(G2&142800;25;2); 97);2)Como la fórmula que muestra el dígito de control (DC) del IBAN.
2. Ir a: Celda J2 / Escribir:=”ES”&DERECHA(0&98 -RESIDUO (RESIDUO(RESIDUO(RESIDUO (EXTRAE(G2;1;8);97)&EXTRAE(G2;9;8); 97)& EXTRAE(G2&142800;17;8); 97)& EXTRAE(G2&142800;25;2); 97);2)&G2Como la fórmula que muestra el código completo del IBAN.

• PRIMER DÍGITO DE CONTROL:

1. El primer dígito de la entidad se multiplica por 4.
2. El segundo dígito de la entidad se multiplica por 8./p>
3. El tercer dígito de la entidad se multiplica por 5./p>
4. El cuarto dígito de la entidad se multiplica por 10./p>
5. El primer dígito de la oficina se multiplica por 9./p>
6. El segundo dígito de la oficina se multiplica por 7./p>
7. El tercer dígito de la oficina se multiplica por 3./p>
8. El cuarto dígito de la oficina se multiplica por 6./p>
9. Se suman todos los resultados.
10. Se divide entre 11 y nos quedamos con el resto de la división./p>
11. A 11 le quitamos el resto anterior, Si el dígito es 11, le asignamos 0, si es 10, le asignamos 1./p>

• SEGUNDO DÍGITO DE CONTROL:

1. El primer dígito del número de cuenta se multiplica por 1.
2. El segundo dígito del número de cuenta se multiplica por 2.
3. El tercer dígito del número de cuenta se multiplica por 4.
4. El cuarto dígito del número de cuenta se multiplica por 8.
5. El quinto dígito del número de cuenta se multiplica por 5.
6. El sexto dígito del número de cuenta se multiplica por 10.
7. El séptimo dígito del número de cuenta se multiplica por 9.
8. El octavo dígito del número de cuenta se multiplica por 7.
9. El noveno dígito del número de cuenta se multiplica por 3.
10. El décimo dígito del número de cuenta se multiplica por 6.
11. Se suman todos los resultados.
12. Se divide entre 11 y nos quedamos con el resto de la división.
13. A 11 le quitamos el resto anterior, Si el dígito es 11, le asignamos 0, si es 10, le asignamos 1.

Mediante funciones podemos obtener el Dígito de Control de la entidad bancaria en Excel.

Nivel de dificultad:  Excel Avanzado