Prioridad de los operadores Excel

Compatibilidad: Truco compatible con Excel 365Truco compatible con Excel 2016Truco compatible con Excel 2013Truco compatible con Excel 2010Truco compatible con Excel 2007

Si combinamos varios operadores en una única fórmula, Excel ejecutará las operaciones en el orden de prioridad siguiente (prioridad de los operadores Excel):

Nº PrioridadOperadorDescripción
1: (dos puntos)
(espacio)
, (coma)
Operadores de referencia
2Negación
3%Porcentaje
4^Exponenciación
5* y /Multiplicación y División
6+ y –Suma y Resta
7&Conecta dos textos
8= < > <= >= <>Operadores comparación
Si una fórmula contiene operadores con la misma prioridad (por ejemplo, si una fórmula contiene un operador de multiplicación y otro de división), Excel evaluará los operadores de izquierda a derecha.
  • PRIORIDAD VARIOS OPERADORES
  1. Ir a: Celda B1 / Escribir: =6+4*3. Mostrará 18, al ser la multiplicación de 4 por 3, a continuación, suma 6 al resultado.

    Realizamos el mismo cálculo de la celda B2, situando entre paréntesis la parte de la fórmula que se calculará en primer lugar.

  2. Ir a: Celda B2 / Escribir: =(6+4)*3. Mostrará 30, al ser la suma de 6 más 4 y, a continuación, multiplica 3 el resultado.

Prioridad de los operadores Excel: Celda B1 con fórmula 6+4*3 y celda B2 con fórmula (6+4)*3
  • VALOR ACTUAL DE UNA ANUALIDAD VENCIDA

Deseamos escribir la fórmula financiera del valor actual de una anualidad vencida.

Fórmula del valor presente de una anualidad vencida

En fórmulas complejas, podemos descomponerla por expresiones:

– Celda B6, =B1

– Celda B7, =(1+B2)^B3-1

– Celda B8, =B2*(1+B2)^B3

– Celda B9, =B6*(B7/B8). Como la anidación de las expresiones de B6, B7 y B8.

Prioridad de los operadores: Celda B9 con fórmula simplificada por expresión y B12 completa.

– Celda B12, =B6*((1+B2)^B3-1)/(B2*(1+B2)^B3). Como la expresión completa.

  • VALOR ACTUAL DIFERIDO DE UN GRADIENTE ARITMÉTICO

Deseamos escribir la fórmula financiera del valor actual diferido de un gradiente aritmético.

Fórmula del valor presente diferido de un gradiente aritmético

En fórmulas complejas, podemos descomponerla por expresiones:

– Celda B9, =B1*(((1+B3)^B4)-1)/(B3*(1+B3)^B4)

– Celda B10, =B2/B3

– Celda B11, =(((1+B3)^B4)-1)/(B3*(1+B3)^B4)

– Celda B12, =B4/((1+B3)^B4)

– Celda B13, =(1+B3)*(1+B6)^-B5

– Celda B14, =(B9+B10*(B11-B12))*B13 Como la anidación de las expresiones de B9, B10, B11, B12 Y B13.

Prioridad de los operadores: Celda B14 con fórmula simplificada por expresión y B17 completa.

Celda B17, =(B1*(((1+B3)^B4)-1)/ (B3*(1+B3)^B4)+ (B2/B3)*((((1+B3)^B4)-1)/ (B3*(1+B3)^B4)-B4/((1+B3)^B4)))* ((1+B3)*(1+B6)^-B5) Como la expresión completa.

Así podemos considerar cuando situar paréntesis en las fórmulas según la prioridad de los operadores.

Nivel de dificultad: Básico Excel Básico

Deja un comentario

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *